home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga Format CD 38
/
Amiga Format CD38 (1999-03-15)(Future Publishing)(GB)(Track 1 of 3)[!][issue 1999-04].iso
/
-websites-
/
haage&partner
/
ftp
/
softlogik
/
pgs33a_33.lha
/
3.3a
/
help.lha
/
help.rexx
Wrap
OS/2 REXX Batch file
|
1997-11-07
|
2KB
|
68 lines
/*
Copyright 1997 SoftLogik Publishing Corporation
May not be distributed without SoftLogik Publishing Corporation's express written permission
$VER: Help.rexx 1.1 (97.11.07)
*/
OPTIONS RESULTS
TRACE OFF
/* Make sure rexx support is opened */
IF ~SHOW('L','rexxsupport.library') THEN
CALL ADDLIB('rexxsupport.library',0,-30)
helppath = arg(1)
href = arg(2)
anchor = arg(3)
/* The next three lines say: */
/* 1) Form a queue (before starting or send commands to HHV.) */
/* 2) See who is at the front of the queue. */
/* 3) If you're not at the front of the queue, */
/* leave by the nearest EXIT. */
call setclip('Own_HHV', getclip('Own_HHV') || pragma('I'))
parse value getclip('Own_HHV') with Owner 9
if Owner ~= pragma('I') then exit
if ~show(P, 'HHV') then do
/* Run help viewer */
ADDRESS COMMAND
'run >nil: pagestream3:hhv SETPATH='helppath
/* Wait until the ARexx port shows up */
do 20
if ~show(P, 'HHV') then call delay(50)
end
/* If the ARexx port didn't show up, alert the user and exit */
if ~show(P, 'HHV') then do
/* The next line resets 'Own_HHV' to '' so that */
/* LATER instances of help.rexx don't just exit. */
call setclip('Own_HHV')
EXIT
end
ADDRESS 'HHV'
end
else do
ADDRESS 'HHV'
'setpath 'helppath
end
'screentofront'
if anchor~='' then href=href'#'anchor
'currenturl'
if (RC = 0) then do
'goto 'href
end
else do
'open 'href
end
/* The next line resets 'Own_HHV' to '' so that */
/* LATER instances of help.rexx don't just exit. */
call setclip('Own_HHV')